Tekst informacyjny o polityce Cookies Close   
    
 
         
• Strona główna
• 1. Linki
• 3. Kontakt: e-Mail
 
         
• 1. Baza danych
• 2. Tabele i kwerendy
• 3. Formularze
• 4. Raporty
• 5. Moduły i makra
• 6. Obsługa błędów
 
    

II.   VBA 

    
• 1. Okna Accessa
• 2. Okna Formularzy
• 3.Okna Dialogowe
• 4. Tekst
• 5. Liczby
• 6. Pliki
• 7. Inne
 
    

III.   API 

    
• 1. Ogólnie o API
• 2. Funkcje API
• 3. System
• 4. Praca z oknami
• 5. Okna dialogowe
• 6. API - Inne
 
         
• 1. Bitmapy 24 Bit
• 2. GDI i HDC
• 3. Kody kreskowe
• 4. Formant Image
• 5. FreeImage.dll
 
    

V.   Inne 

    
• 1. Shell i MsDOS
• 2. Kontrolki
• 3. ६ԼҚ ਸ
• 4. Unikod

 
Odwiedzin:


Logo - BraZby

Logo AccessFAQ• I.1. Access - baza danych cz. 1 •

1.1 Jak pobrać ścieżkę folderu bazy danych ?
1.2 Jak pobrać nazwę pliku bazy danych ?
1.3 Jak otworzyć drugą bazę danych ?
1.4 Jak pokazać (ukryć) okno bazy danych ?
1.5 Jak sprawdzić, czy baza danych otwarta jest na wyłączność ?
1.6 Jak zmienić ("usunąć") pojawiającą się podczas startu bitmapę Accessa ?
1.7 Zniknęły mi niektóre obiekty w oknie bazy => Opcje bazy danych (SetOption) ?
1.8 Jak zmienić ikonę i tytuł okna Accessa, jak zabezpieczyć bazę przed klawiszem SHIFT => Opcje startowe bazy (Autostart) ?
1.9 Zabezpieczyłem bazę danych (plik *.mdb) za pomocą opcji startowych i nie mogę wejść w tryb projektowania. Co robić ?
1.10 Jak otworzyć bazę zabezpieczoną hasłem ?
1.11 Jak uniemożliwić otwarcie drugiej instancji bazy ?
1.12 Jak sprawdzić, czy jest otwarta druga instancja MS Access ?
1.13 Jak zapamiętać dane konfiguracyjne by zawsze były dostępne ?
1.14 Jak wylistować wszystkie utworzone obiekty w bazie ?
1.15 Jak odzyskać uszkodzona bazę, (plik bazy istniejący przed ostatnią defragmentacją) ?


1.7 Zniknęły mi niektóre obiekty w oknie bazy => Opcje bazy danych (SetOption) ?

' Menu: Narzędzia / Opcje / Karta "Widok"
' • należy zaznaczyć pole wyboru "Pokazuj ukryte obiekty"

' lub za pomocą VBA: przykładowe wywołania:
 '1. Dla pola wyboru: - argumentem jest wartość logiczna: True lub False
'Application.SetOption "Show Hidden Objects", True
 '2. Dla pola tekstowego: - argumentem jest ciąg znaków
'Application.SetOption "Default Database Directory", "C:\"
 '3. Dla przycisku opcji w grupie opcji, opcja w polu kombi lub w polu listy:
    '- argumentem jest pozycja opcji w grupie opcji lub na liście (licząc od zera [0])
'Application.SetOption "Error Trapping", 1
'Application.SetOption "New Database Sort Order", 8



' jak pobrać opcje bazy danych:
Private Sub zbEnumOptions()
Dim aOpt(1 To 73) As String * 55
Dim aArg(1 To 73) As String
Dim i As Integer

      ' Opcje bazy danych:
' Karta Widok
aOpt(1)="Pasek stanu":aArg(1)="Show Status Bar"
aOpt(2)="Startowe okno dialogowe":aArg(2)="Show Startup Dialog Box"
aOpt(3)="Obiekty ukryte":aArg(3)="Show Hidden Objects"
aOpt(4)="Obiekty systemowe":aArg(4)="Show System Objects"
aOpt(5)="Kolumnę nazw":aArg(5)="Show Macro Names Column"
aOpt(6)="Kolumnę warunków":aArg(6)="Show Conditions Column"
' Karta Ogólne
aOpt(7)="Lewy margines":aArg(7)="Left Margin"
aOpt(8)="Prawy margines":aArg(8)="Right Margin"
aOpt(9)="Górny margines":aArg(9)="Top Margin"
aOpt(10)="Dolny margines":aArg(10)="Bottom Margin"
aOpt(11)="Domyślny folder bazy danych":aArg(11)="Default Database Directory"
aOpt(12)="Nowy porządek sortowania baz danych":aArg(12)="New Database Sort Order"
aOpt(13)="Dźwięk przy zdarzeniu":aArg(13)="Provide Feedback with Sound"
' Karta hiperłącza / HTML
aOpt(14)="Kolor hiperłącza":aArg(14)="Hyperlink Color"
aOpt(15)="Kolor obejrzanych hiperłączy":aArg(15)="Followed Hyperlink Color"
aOpt(16)="Podkreślaj hiperłącza":aArg(16)="Underline Hyperlinks"
aOpt(17)="Pokazuj adres hiperłącza na pasku stanu":aArg(17)="Show Hyperlink Addresses in Status Bar"
aOpt(18)="Szablon HTML":aArg(18)="HTML Template"
aOpt(19)="Nazwa źródła danych":aArg(19)="Data Source Name"
aOpt(20)="Użytkownik połączony jako":aArg(20)="User Name"
aOpt(21)="Hasło dla użytkownika":aArg(21)="Password"
aOpt(22)="URL serwera":aArg(22)="Active Server Pages URL"
' ActiveX Server URL
aOpt(23)="Limit czasu sesji":aArg(23)="Active Server Pages Session Timeout" ' ActiveX Session Timeout
' Karta Edytuj / Znajdź
aOpt(24)="Domyślne działanie Znajdź/Zamień":aArg(24)="Default Find/Replace Behavior"
aOpt(25)="Zmiany rekordu":aArg(25)="Confirm Record Changes"
aOpt(26)="Usuwanie dokumentów":aArg(26)="Confirm Document Deletions"
aOpt(27)="Kwerendy funkcjonalne":aArg(27)="Confirm Action Queries"
aOpt(28)="Lokalnych polach indeksowanych":aArg(28)="Show Values in Indexed"
aOpt(29)="Lokalnych polach nieindeksowanych":aArg(29)="Show Values in Non-indexed"
aOpt(30)="Polach ODBC":aArg(30)="Show Values in Remote"
aOpt(31)="Nie wyświetlaj list, w których wierszy jest więcej niż":aArg(31)="Show Values Limit"
' Karta Klawiatura
aOpt(32)="Przenieś po ENTER":aArg(32)="Move After Enter"
aOpt(33)="Działanie klawiszy strzałek":aArg(33)="Arrow Key Behavior"
aOpt(34)="Przy wejściu do pola":aArg(34)="Behavior Entering Field"
aOpt(35)="Kursor zatrzymuje się w pierwszym/ostatnim polu":aArg(35)="Cursor Stops at First/Last Field"
' Karta Arkusz danych
aOpt(36)="Kolory domyślne: Czcionka":aArg(36)="Default Font Color"
aOpt(37)="Kolory domyślne: Tło":aArg(37)="Default Background Color"
aOpt(38)="Kolory domyślne: Linie siatki":aArg(38)="Default Gridlines Color"
aOpt(39)="Czcionka domyślna: Czcionka":aArg(39)="Default Font Name"
aOpt(40)="Czcionka domyślna: Grubość":aArg(40)="Default Font Weight"
aOpt(41)="Czcionka domyślna: Rozmiar":aArg(41)="Default Font Size"
aOpt(42)="Czcionka domyślna: Kursywa":aArg(42)="Default Font Italic"
aOpt(43)="Czcionka domyślna: Podkreślenie":aArg(43)="Default Font Underline"
aOpt(44)="Poziome":aArg(44)="Default Gridlines Horizontal"
aOpt(45)="Pionowe":aArg(45)="Default Gridlines Vertical"
aOpt(46)="Domyślna szerokość kolumny":aArg(46)="Default Column Width"
aOpt(47)="Domyślny efekt komórek":aArg(47)="Default Cell Effect"
aOpt(48)="Pokazuj animacje":aArg(48)="Show Animations"
' Karta Tabele / Kwerendy
aOpt(49)="Tekst":aArg(49)="Default Text Field Size"
aOpt(50)="Liczba":aArg(50)="Default Number Field Size"
aOpt(51)="Domyślny typ pola":aArg(51)="Default Field Type"
aOpt(52)="Autoindeksowanie przy imporcie/tworzeniu":aArg(52)="AutoIndex on Import/Create"
aOpt(53)="Pokazuj nazwy tabel":aArg(53)="Show Table Names"
aOpt(54)="Wyprowadzaj wszystkie pola":aArg(54)="Output All Fields"
aOpt(55)="Włączaj autosprzęganie":aArg(55)="Enable AutoJoin"
aOpt(56)="Uaktywnij uprawnienia":aArg(56)="Run Permissions"
' Karta Formularze / Raporty
aOpt(57)="Zachowanie podczas zaznaczania":aArg(57)="Selection Behavior"
aOpt(58)="Szablon formularza":aArg(58)="Form Template"
aOpt(59)="Szablon raportu":aArg(59)="Report Template"
aOpt(60)="Zawsze używaj procedur zdarzenia":aArg(60)="Always Use Event Procedures"
' Karta Zaawansowane
aOpt(61)="Domyślne blokowanie rekordów":aArg(61)="Default Record Locking"
aOpt(62)="Domyślny tryb otwierania":aArg(62)="Default Open Mode for Databases"
aOpt(63)="Ignoruj żądania DDE":aArg(63)="Ignore DDE Requests"
aOpt(64)="Włączaj odświeżanie DDE":aArg(64)="Enable DDE Refresh"
aOpt(65)="Limit czasu OLE/DDE (sek)":aArg(65)="OLE/DDE Timeout (Sec)"
aOpt(66)="Liczba prób aktualizacji":aArg(66)="Number of Update Retries"
aOpt(67)="Okres odświeżania ODBC (sek)":aArg(67)="ODBC Refresh Interval (Sec)"
aOpt(68)="Okres odświeżania (sek)":aArg(68)="Refresh Interval (Sec)"
aOpt(69)="Ponawiaj aktualizację po (msek)":aArg(69)="Update Retry Interval (Msec)"
aOpt(70)="Argumenty wiersza poleceń":aArg(70)="Command-Line Arguments"
aOpt(71)="Argumenty kompilacji warunkowej":aArg(71)="Conditional Compilation Arguments"
aOpt(72)="Nazwa projektu":aArg(72)="Project Name"
aOpt(73)="Wychwytywanie błędów":aArg(73)="Error Trapping"

On Error Resume Next
For i = 1 To 73
Debug.Print Format(i, "00"); ". "; aOpt(i); _
Application.GetOption(aArg(i))
If Err.Number <> 0 Then
Debug.Print Format(i, "00"); ". "; _
aOpt(i); "ERROR", Err.Description
Err.Clear
End If
Next
On Error GoTo 0

DoCmd.RunCommand acCmdDebugWindow

End Sub

 ΔΔΔ 

1.8 Jak zmienić ikonę i tytuł okna Accessa, jak zabezpieczyć bazę przed klawiszem SHIFT => Opcje startowe bazy (Autostart) ?


Należy zmienić odpowiednie właściwości bazy za pomcą funkcji:
    object.Properties("name") = value
Jeżeli właściwość nie istnieje (np. nie była utworzona w oknie Autostart), wystąpi błąd, w obsłudze którego należy dodać nową właściwość do kolekcji object.Properties.

• Wybrane właściwości bazy:
Nazwa właściwościTypOpis
AppTitledbTextTytuł aplikacji
AppIcondbTextIkona aplikacji
StartupFormdbTextWyświetl formularz
StartupShowDBWindowdbBooleanWyświetlaj okno bazy danych
StartupShowStatusBardbBooleanWyświetlaj pasek stanu
StartupMenuBardbTextPasek menu
StartupShortcutMenuBardbTextPasek menu podręcznego
AllowFullMenusdbBooleanUżywaj pełnych menu programu Access
AllowShortcutMenusdbBooleanUżywaj domyślnych menu podręcznych
AllowBuiltInToolbarsdbBooleanUżywaj wbudowanych pasków narzędzi
AllowToolbarChangesdbBooleanPozwalaj na zmiany pasków narzędzi/menu
AllowBreakIntoCodedbBooleanWyświetlaj kod po błędzie
AllowBypassKeydbBooleanUżywaj klawisza SHIFT dla opcji startowych
AllowSpecialKeysdbBooleanUżywaj specjalnych klawiszy programu Access

• Działanie klawiszy specjalnych:
  Sekwencja klawiszy  Skutek
(F11) lub ALT+F1Wyświetlenie okna bazy danych na wierzchu
CTRL+GWyświetlenie okna analizy programu
CTRL+F11Przełączanie pomiędzy niestandardowym paskiem menu i wbudowanym paskiem menu
CTRL+BREAKWprowadzenie trybu przerwania i wyświetlenie bieżącego modułu w oknie modułu
SHIFTWciśnięcie podczas startu bazy umożliwia pominięcie opcji startowych tzn. makro Autostart i formularz startowy nie są uruchamiane.
' Większość ustawień opcji startowych obowiązuje dopiero po ponownym uruchomieniu bazy.


' przykładowe wywołanie:
Sub btnTest_Click()
Dim fRet As Boolean

' zmiana tytułu okna i ikony (nie musi to być plik *.ico)
fRet = zbChangeProperty("AppTitle", dbText, "Moja nazwa")
' plik ikony bazy musi istnieć na dysku,
' fRet = zbChangeProperty("AppIcon", dbText, "C:\MojaIkona.bmp)")
Application.RefreshTitleBar

' nie pozwól na użycie klawisza SHIFT do pominięcie opcji startowych bazy,
fRet = zbChangeProperty("AllowBypassKey", dbBoolean, False)

' można także utworzyć swoją właściwość
' fRet = zbChangeProperty("MojaWlasciwosc", dbText, "BleBleBle")

' niepotrzebną właściwość można usunąć z kolekcji,
' (może wystąpić błąd jeżeli właściwość nie istnieje),

' CurrentDb.Properties.Delete ("MojaWlasciwosc")
' CurrentDb.Properties.Delete ("AllowBypassKey")

' pokaż wszystkie właściwości bazy:
Call zbEnumProperties

End Sub


' zmienia właściwość sPrpName bazy, jeżeli właściwość nie istnieje
' to zostaje utworzona i dodana do kolekcji,
' przy powodzeniu zwraca True, w przeciwnym wypadku False

Public Function zbChangeProperty(sPrpName As String, _
vPrpType As Variant, _
vPrpValue As Variant) As Boolean
Dim dbs As Database
Dim prp As Property

On Error Resume Next
Set dbs = CurrentDb
With dbs
IsObject (.Properties(sPrpName))
If Err.Number = 0 Then
On Error GoTo 0
.Properties(sPrpName) = vPrpValue
Else
On Error GoTo 0
Set prp = .CreateProperty(sPrpName, vPrpType, vPrpValue)
.Properties.Append prp
.Properties.Refresh
Set prp = Nothing
End If
End With
Set dbs = Nothing

If Err.Number = 0 Then zbChangeProperty = True

End Function


' jak sprawdzić, które właściwości są ustawione:
Private Sub zbEnumProperties()
Dim dbs As Database
Dim sPrpName As String * 35
Dim vPrpValue
Dim i As Integer

Set dbs = CurrentDb
With dbs
On Error Resume Next
For i = 0 To .Properties.Count - 1
sPrpName = .Properties(i).Name
vPrpValue = .Properties(i).Value

If Err.Number = 0 Then
Debug.Print i, sPrpName; vPrpValue
Else
Err.Clear
Debug.Print i, sPrpName; "ERROR"
End If
Next
On Error GoTo 0
End With
Set dbs = Nothing

DoCmd.RunCommand acCmdDebugWindow

End Sub

 ΔΔΔ